Henry-Hiles/nixos
1
0
Fork 0
Code Issues Pull requests Projects Releases Packages Wiki Activity Actions

Reorganize

Browse source
This commit is contained in:
Henry Hiles 2025-07-12 10:53:06 -04:00
commit b506e8af60
No known key found for this signature in database
27 changed files with 2045 additions and 98 deletions
Download patch file Download diff file Expand all files Collapse all files

7
modules/graphical/dconf/burn-my-windows.conf Normal file
View file

@ -0,0 +1,7 @@
[burn-my-windows-profile]
fire-enable-effect=false
apparition-enable-effect=false
broken-glass-enable-effect=false
energize-a-enable-effect=false
energize-b-enable-effect=false
glide-enable-effect=true

130
modules/graphical/dconf/default.nix Normal file
View file

@ -0,0 +1,130 @@
{
lib,
pkgs,
...
}: {
programs.dconf.profiles.user.databases = [
{
# Can't lock because of home manager
# lockAll = true;
settings = lib.mapAttrs (_:
lib.mapAttrs (name: value:
if builtins.isInt value
then lib.gvariant.mkInt32 value
else value)) (with lib.gvariant; {
"org/gnome/shell/extensions/rounded-window-corners-reborn" = {
border-width = -5;
skip-libadwaita-app = false;
skip-libhandy-app = false;
};
"org/gnome/shell/extensions/pop-shell" = rec {
active-hint = true;
tile-by-default = true;
active-hint-border-radius = mkUint32 16;
gap-inner = mkUint32 3;
gap-outer = gap-inner;
};
"org/gnome/shell/extensions/just-perfection" = {
accessibility-menu = false;
activities-button = true;
calendar = true;
clock-menu = true;
clock-menu-position = 0;
dash = false;
dash-app-running = false;
dash-separator = false;
events-button = false;
keyboard-layout = false;
panel-size = 0;
power-icon = true;
quick-settings = true;
quick-settings-dark-mode = false;
show-apps-button = false;
startup-status = 0;
window-menu-take-screenshot-button = false;
window-picker-icon = true;
workspace = true;
workspace-switcher-size = 0;
world-clock = false;
};
"org/gnome/shell/extensions/display-brightness-ddcutil" = {
allow-zero-brightness = true;
button-location = 1;
ddcutil-binary-path = lib.meta.getExe pkgs.ddcutil;
ddcutil-queue-ms = 130.0;
ddcutil-sleep-multiplier = 40.0;
decrease-brightness-shortcut = ["XF86MonBrightnessDown"];
increase-brightness-shortcut = ["XF86MonBrightnessUp"];
hide-system-indicator = true;
only-all-slider = true;
position-system-menu = 3.0;
show-internal-slider = false;
show-all-slider = true;
show-display-name = false;
show-osd = true;
show-value-label = false;
step-change-keyboard = 2.0;
};
"org/gnome/shell/extensions/burn-my-windows".active-profile = toString ./burn-my-windows.conf;
"org/gnome/desktop/wm/preferences".focus-mode = "mouse";
"org/gnome/shell" = {
disable-user-extensions = true;
enabled-extensions = [
"blur-my-shell@aunetx"
"caffeine@patapon.info"
"pop-shell@system76.com"
"rounded-window-corners@fxgn"
"burn-my-windows@schneegans.github.com"
"fullscreen-avoider@noobsai.github.com"
"appindicatorsupport@rgcjonas.gmail.com"
"compiz-windows-effect@hermes83.github.com"
"user-theme@gnome-shell-extensions.gcampax.github.com"
"display-brightness-ddcutil@themightydeity.github.com"
"launch-new-instance@gnome-shell-extensions.gcampax.github.com"
];
disabled-extensions = [
"just-perfection-desktop@just-perfection"
];
};
"org/gnome/settings-daemon/plugins/media-keys".custom-keybindings = ["/org/gnome/settings-daemon/plugins/media-keys/custom-keybindings/custom0/"];
"org/gnome/settings-daemon/plugins/media-keys/custom-keybindings/custom0" = {
binding = "<Super>e";
command = "nautilus";
name = "Files";
};
"org/gnome/desktop/search-providers".sort-order = ["org.gnome.Contacts.desktop" "org.gnome.Documents.desktop" "org.gnome.Nautilus.desktop"];
"org/gnome/desktop/interface" = rec {
color-scheme = "prefer-dark";
enable-animations = true;
cursor-theme = "GoogleDot-Blue";
cursor-size = 24;
gtk-theme = "adw-gtk3";
icon-theme = "Papirus";
toolkit-accessibility = false;
font-hinting = "slight";
font-antialiasing = "grayscale";
font-name = "sans";
document-font-name = font-name;
monospace-font-name = "monospace";
};
# "org/gnome/Ptyxis".default-profile-uuid = "quadradical";
#
# "org/gnome/Ptyxis/Profiles/quadradical".palette = "nord";
});
}
];
}

8
modules/graphical/desktop.nix Normal file
View file

@ -0,0 +1,8 @@
{
environment.sessionVariables.NIXOS_OZONE_WL = "1";
services = {
desktopManager.gnome.enable = true;
displayManager.gdm.enable = true;
};
}

12
modules/graphical/fonts.nix Normal file
View file

@ -0,0 +1,12 @@
{pkgs, ...}: {
fonts = {
enableDefaultPackages = false;
packages = with pkgs; [inter nerd-fonts.fira-code twitter-color-emoji];
fontconfig.defaultFonts = rec {
serif = ["Inter"];
sansSerif = serif;
monospace = ["FiraCode Nerd Font"];
emoji = ["Twitter Color Emoji"];
};
};
}

41
modules/graphical/gnome.nix Normal file
View file

@ -0,0 +1,41 @@
{pkgs, ...}: {
programs.nautilus-open-any-terminal = {
enable = true;
terminal = "ptyxis";
};
environment = {
sessionVariables.XDG_CURRENT_DESKTOP = "GNOME";
systemPackages = with pkgs.gnomeExtensions; [
caffeine
pop-shell
appindicator
blur-my-shell
just-perfection
burn-my-windows
fullscreen-avoider
launch-new-instance
compiz-windows-effect
rounded-window-corners-reborn
brightness-control-using-ddcutil
];
gnome.excludePackages = with pkgs; [
yelp
totem
xterm
evince
snapshot
epiphany
gnome-logs
gnome-tour
gnome-music
gnome-console
gnome-software
gnome-characters
gnome-text-editor
gnome-system-monitor
];
};
}

1
modules/graphical/goldwarden.nix Normal file
View file

@ -0,0 +1 @@
{programs.goldwarden.enable = true;}

1
modules/graphical/graphics.nix Normal file
View file

@ -0,0 +1 @@
{hardware.graphics.enable = true;}

136
modules/graphical/librewolf/customChrome.css Normal file
View file

@ -0,0 +1,136 @@
@namespace xul url("http://www.mozilla.org/keymaster/gatekeeper/there.is.only.xul");
@media (prefers-color-scheme: dark) {
:root {
/* Browser area before a page starts loading */
--gnome-browser-before-load-background: #2e3440;
/* Accent */
--gnome-accent-bg: #3584e4;
--gnome-accent: #78aeed;
/* Toolbars */
--gnome-toolbar-background: var(--gnome-headerbar-background);
--gnome-toolbar-color: #d8dee9;
--gnome-toolbar-border-color: rgba(0, 0, 0, 0.36);
--gnome-toolbar-icon-fill: #eeeeec;
--gnome-inactive-toolbar-color: #919190;
--gnome-inactive-toolbar-background: var(
--gnome-inactive-headerbar-background
);
--gnome-inactive-toolbar-border-color: var(
--gnome-toolbar-border-color
);
--gnome-inactive-toolbar-icon-fill: #919190;
/* Sidebar */
--gnome-sidebar-background: var(--gnome-toolbar-background);
--gnome-inactive-sidebar-background: var(--gnome-sidebar-background);
/* Menus */
--gnome-menu-background: #3b4252;
--gnome-menu-border-color: rgba(0, 0, 0, 0.14);
--gnome-menu-shadow: 0 1px 5px 1px rgba(0, 0, 0, 0.09),
0 2px 14px 3px rgba(0, 0, 0, 0.05);
--gnome-menu-button-hover-background: var(--gnome-button-background);
--gnome-menu-separator-color: rgba(255, 255, 255, 0.1);
/* Header bar */
--gnome-headerbar-background: #2e3440;
--gnome-headerbar-border-color: var(--gnome-toolbar-border-color);
/* --gnome-inactive-headerbar-background: var(--gnome-browser-before-load-background);*/
--gnome-inactive-headerbar-background: #3b4252;
--gnome-inactive-headerbar-border-color: var(
--gnome-inactive-toolbar-border-color
);
/* Buttons */
--gnome-button-background: rgba(255, 255, 255, 0.1);
--gnome-button-hover-background: rgba(255, 255, 255, 0.15);
--gnome-button-active-background: rgba(255, 255, 255, 0.3);
--gnome-button-flat-hover-background: rgba(255, 255, 255, 0.07);
--gnome-button-flat-active-background: rgba(255, 255, 255, 0.1);
--gnome-button-suggested-action-background: var(--gnome-accent-bg);
--gnome-button-destructive-action-background: #e01b24;
--gnome-button-close-background: var(
--gnome-button-flat-hover-background
);
--gnome-button-hover-close-background: var(
--gnome-button-hover-background
);
--gnome-button-active-close-background: var(
--gnome-button-active-background
);
--gnome-toolbar-star-button: #f8e45c;
/* Entries */
--gnome-entry-background: rgba(255, 255, 255, 0.1);
--gnome-entry-color: #d8dee9;
--gnome-inactive-entry-color: #d6d6d6;
--gnome-focused-urlbar-border-color: rgba(
120,
174,
237,
0.5
); /* Same as --gnome-accent but with opacity*/
/* Switch */
--gnome-switch-background: rgba(255, 255, 255, 0.15);
--gnome-switch-slider-background: #d2d2d2;
--gnome-switch-active-background: var(--gnome-accent-bg);
--gnome-switch-active-slider-background: #d8dee9;
/* Tabs */
--gnome-tabbar-background: var(--gnome-headerbar-background);
--gnome-tabbar-tab-separator-color: rgba(255, 255, 255, 0.15);
--gnome-tabbar-tab-hover-background: #3a404b; /* Hardcoded color */
--gnome-tabbar-tab-active-background: #3f4551; /* Hardcoded color */
--gnome-tabbar-tab-active-background-contrast: #616979; /* Hardcoded color */
--gnome-tabbar-tab-active-hover-background: #444a56; /* Hardcoded color */
--gnome-inactive-tabbar-background: var(
--gnome-inactive-headerbar-background
);
--gnome-inactive-tabbar-tab-hover-background: #404857; /* Hardcoded color */
--gnome-inactive-tabbar-tab-active-background: #434a59; /* Hardcoded color */
--gnome-tab-button-background: rgba(0, 0, 0, 0.5);
--gnome-tab-button-hover-background: rgba(0, 0, 0, 0.6);
--gnome-tabbar-tab-identity-base-opacity: 0;
--gnome-tabbar-tab-needs-attetion: #546f8e;
}
/* Private window colors */
:root {
--gnome-private-accent: #71a1db;
/* Toolbars */
--gnome-private-toolbar-background: #1c2438;
--gnome-private-inactive-toolbar-background: var(
--gnome-private-toolbar-background
);
/* Menus */
--gnome-private-menu-background: #252f49;
/* Header bar */
--gnome-private-headerbar-background: #252f49;
--gnome-private-inactive-headerbar-background: var(
--gnome-private-toolbar-background
);
/* Tabs */
--gnome-private-tabbar-tab-hover-background: #343e56; /* Hardcoded color */
--gnome-private-tabbar-tab-active-background: #343e56; /* Hardcoded color */
--gnome-private-tabbar-tab-active-background-contrast: #495675; /* Hardcoded color */
--gnome-private-tabbar-tab-active-hover-background: #414a61; /* Hardcoded color */
--gnome-private-inactive-tabbar-tab-hover-background: #242c3f; /* Hardcoded color */
--gnome-private-inactive-tabbar-tab-active-background: #272e41; /* Hardcoded color */
/* Text color for Firefox Logo in new private tab */
--gnome-private-wordmark: #fbfbfe;
/* New private tab background */
--gnome-private-in-content-page-background: #1c2438;
/* Private browsing info box */
--gnome-private-text-primary-color: #fbfbfe;
}
}

1
modules/graphical/librewolf/customContent.css Symbolic link
View file

@ -0,0 +1 @@
customChrome.css

171
modules/graphical/librewolf/default.nix Normal file
View file

@ -0,0 +1,171 @@
{
lib,
pkgs,
config,
inputs,
...
}: {
environment.etc."librewolf/policies/policies.json".source = config.environment.etc."firefox/policies/policies.json".source;
systemd.tmpfiles.settings.librewolf = {
"/home/quadradical/.librewolf"."d".user = "quadradical";
"/home/quadradical/.librewolf/quadradical"."d".user = "quadradical";
"/home/quadradical/.librewolf/profiles.ini"."L+".argument = toString ((pkgs.formats.ini {}).generate "profiles.ini" {
General = {
StartWithLastProfile = 1;
};
Profile0 = rec {
Default = 1;
IsRelative = 1;
Name = "quadradical";
Path = Name;
};
});
"/home/quadradical/.librewolf/quadradical/chrome"."L+".argument =
toString
(pkgs.symlinkJoin {
name = "firefox-gnome-theme";
paths = [./. inputs.firefox-gnome-theme];
});
};
programs.firefox = {
enable = true;
package = pkgs.librewolf;
autoConfig = lib.concatStringsSep "\n" (lib.mapAttrsToList (pref: value: "lockPref(\"${pref}\", ${builtins.toJSON value});") {
"webgl.disabled" = false;
"media.peerconnection.enabled" = true;
"privacy.resistFingerprinting" = false;
"privacy.fingerprintingProtection" = true;
"browser.discovery.containers.enabled" = false;
"svg.context-properties.content.enabled" = true;
"toolkit.legacyUserProfileCustomizations.stylesheets" = true;
"privacy.fingerprintingProtection.overrides" = "+AllTargets,-CSSPrefersColorScheme";
"browser.uiCustomization.state" = "{\"placements\":{\"widget-overflow-fixed-list\":[],\"unified-extensions-area\":[],\"nav-bar\":[\"back-button\",\"forward-button\",\"stop-reload-button\",\"urlbar-container\",\"downloads-button\"],\"toolbar-menubar\":[\"menubar-items\"],\"TabsToolbar\":[\"tabbrowser-tabs\",\"new-tab-button\",\"alltabs-button\"],\"PersonalToolbar\":[\"personal-bookmarks\"]},\"seen\":[\"save-to-pocket-button\",\"developer-button\"],\"dirtyAreaCache\":[\"nav-bar\",\"PersonalToolbar\",\"toolbar-menubar\",\"TabsToolbar\"],\"currentVersion\":19}";
});
policies = {
ShowHomeButton = false;
DisableAccounts = true;
DisableFormHistory = true;
DisableFirefoxScreenshots = true;
DisableSetDesktopBackground = true;
DisableMasterPasswordCreation = true;
# We use the Bitwarden extension for these
PasswordManagerEnabled = false;
AutofillAddressEnabled = false;
AutofillCreditCardEnabled = false;
SanitizeOnShutdown = {
Cache = false;
Cookies = false;
Downloads = true;
FormData = true;
History = false;
Sessions = false;
SiteSettings = false;
OfflineApps = true;
Locked = true;
};
DontCheckDefaultBrowser = true;
HttpsOnlyMode = "force_enabled";
DisplayMenuBar = "never";
DisplayBookmarksToolbar = "never";
DNSOverHTTPS.Enabled = false;
EnableTrackingProtection = {
Value = true;
Locked = true;
Cryptomining = true;
Fingerprinting = true;
};
UserMessaging = {
WhatsNew = false;
ExtensionRecommendations = false;
FeatureRecommendations = false;
UrlbarInterventions = false;
SkipOnboarding = true;
MoreFromMozilla = false;
FirefoxLabs = false;
};
FirefoxHome = {
TopSites = true;
SponsoredTopSites = false;
Pocket = false;
Snippets = false;
Highlights = false;
Locked = true;
};
FirefoxSuggest = {
WebSuggestions = false;
SponsoredSuggestions = false;
ImproveSuggest = false;
Locked = true;
};
ExtensionSettings = lib.mkForce (lib.listToAttrs (map (id: {
name = id;
value = {
install_url = "https://addons.mozilla.org/en-US/firefox/downloads/latest/${id}/latest.xpi";
installation_mode = "force_installed";
};
}) [
"historyblock@kain"
"uBlock0@raymondhill.net"
"sponsorBlocker@ajay.app"
"jid1-MnnxcxisBPnSXQ@jetpack" # Privacy Badger
"frankerfacez@frankerfacez.com"
"7esoorv3@alefvanoon.anonaddy.me" # LibRedirect
"{de621c74-2aa6-4c91-a2da-28d445b66bab}" # YouTube Livestreams Theater Mode
"{cf3dba12-a848-4f68-8e2d-f9fadc0721de}" # Google Lighthouse
"{446900e4-71c2-419f-a6a7-df9c091e268b}" # Bitwarden
"{4ce83447-8255-43c2-b8f7-e02eb8c2cc39}" # Draw on Page
"{ac34afe8-3a2e-4201-b745-346c0cf6ec7d}" # Better Youtube Shorts
"{2327d818-55d3-441d-aea2-8b44aa2cb9aa}" # Toggle Website Colors
"{a6c4a591-f1b2-4f03-b3ff-767e5bedf4e7}" # User-Agent Switcher and Manager
"enhancerforyoutube@maximerf.addons.mozilla.org"
]));
SearchEngines = {
Default = "Federated Nexus Search";
PreventInstalls = true;
Add = [
{
Name = "Federated Nexus Search";
URLTemplate = "https://search.federated.nexus/search?q={searchTerms}";
IconURL = "https://federated.nexus/images/icon.svg";
}
{
Name = "Nix Package Search";
URLTemplate = "https://search.nixos.org/packages?channel=unstable&query={searchTerms}";
IconURL = "https://github.com/NixOS/nixos-artwork/raw/refs/heads/master/logo/nix-snowflake-white.svg";
Alias = "np";
}
{
Name = "NixOS Option Search";
URLTemplate = "https://search.nixos.org/options?channel=unstable&query={searchTerms}";
IconURL = "https://github.com/NixOS/nixos-artwork/raw/refs/heads/master/logo/nix-snowflake-white.svg";
Alias = "no";
}
{
Name = "NixOS Wiki";
URLTemplate = "https://wiki.nixos.org/w/index.php?search={searchTerms}";
IconURL = "https://github.com/NixOS/nixos-artwork/raw/refs/heads/master/logo/nix-snowflake-white.svg";
Alias = "nw";
}
];
};
};
};
}

1
modules/graphical/mac.nix Normal file
View file

@ -0,0 +1 @@
{networking.networkmanager.wifi.macAddress = "random";}

1
modules/graphical/noisetorch.nix Normal file
View file

@ -0,0 +1 @@
{programs.noisetorch.enable = true;}

14
modules/graphical/packages.nix Normal file
View file

@ -0,0 +1,14 @@
{pkgs, ...}: {
services.xserver.excludePackages = [pkgs.xterm];
environment.systemPackages = with pkgs; [
tuba
ptyxis
gapless
resources
wl-clipboard
google-cursor
authenticator
cinny-desktop
papirus-icon-theme
];
}

13
modules/graphical/pipewire.nix Normal file
View file

@ -0,0 +1,13 @@
{
services = {
pulseaudio.enable = false;
pipewire = {
enable = true;
alsa = {
enable = true;
support32Bit = true;
};
pulse.enable = true;
};
};
}

1
modules/graphical/plymouth.nix Normal file
View file

@ -0,0 +1 @@
{boot.plymouth.enable = true;}

11
modules/graphical/print.nix Normal file
View file

@ -0,0 +1,11 @@
{
services = {
avahi = {
enable = true;
nssmdns4 = true;
openFirewall = true;
};
printing.enable = true;
};
}

7
modules/graphical/run0.nix Normal file
View file

@ -0,0 +1,7 @@
{
# TODO: Server too
security = {
polkit.persistentAuthentication = true;
run0-sudo-shim.enable = true;
};
}

7
modules/graphical/ssh.nix Normal file
View file

@ -0,0 +1,7 @@
{
programs.ssh.extraConfig = ''
Host server
HostName ssh.federated.nexus
Port 2222
'';
}