imagey/flake.nix

{
  inputs = {
    nixpkgs.url = "https://channels.nixos.org/nixos-unstable/nixexprs.tar.zst";

    crane.url = "github:ipetkov/crane";

    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs =
    inputs:
    inputs.flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import inputs.nixpkgs { inherit system; };
        lib = pkgs.lib;
        craneLib = inputs.crane.mkLib pkgs;

        cargoToml = fromTOML (builtins.readFile ./Cargo.toml);
        name = cargoToml.package.name;

        dlDeps =
          with pkgs;
          [
            # needed for both x11 and wayland
            libxkbcommon
            libGL

            libx11
            libxcursor
            libxi
            libxcb
          ]
          ++ lib.optionals stdenv.hostPlatform.isLinux [
            # libdbus, for rfd
            dbus.lib

            vulkan-loader
            wayland
          ];

        commonArgs = {
          # all that's needed for artifacts and checks
          nativeBuildInputs = with pkgs; [
            pkg-config
          ];
          buildInputs = with pkgs; [
            dav1d
          ];

          src = ./.;
        };

        # Build *just* the cargo dependencies,
        # to reuse them for build and test derivations.
        cargoArtifacts = craneLib.buildDepsOnly commonArgs;

        # Build the actual crate itself,
        # reusing the dependency artifacts from above.
        crate =
          let
            desktopItem = pkgs.makeDesktopItem {
              inherit name;
              desktopName = name;
              icon = name;
              exec = name;
              mimeTypes = [
                "image/png"
                "image/jpeg"
                "image/gif"
                "image/webp"
                "image/avif"
                "image/jxl"
                "image/tiff"
                "image/bmp"
                "image/vnd.microsoft.icon" # .ico
                "application/x-krita"
                "image/svg+xml"
              ];
            };
          in
          craneLib.buildPackage (
            commonArgs
            // {
              inherit cargoArtifacts;

              nativeBuildInputs = commonArgs.nativeBuildInputs ++ [
                pkgs.autoPatchelfHook
              ];

              buildInputs = commonArgs.buildInputs ++ [
                pkgs.libgcc
              ];

              runtimeDependencies = dlDeps;

              doCheck = false;

              postFixup = ''
                mkdir -p "$out/share/applications"
                ln -s "${desktopItem}"/share/applications/* "$out/share/applications/"
              '';
            }
          );
      in
      {
        packages.default = crate;

        checks = {
          crate-clippy = craneLib.cargoClippy (
            commonArgs
            // {
              inherit cargoArtifacts;

              cargoClippyExtraArgs = "-- --deny warnings";
            }
          );
        };

        devShells.default = craneLib.devShell {
          LD_LIBRARY_PATH = lib.makeLibraryPath dlDeps;

          inputsFrom = [ crate ];
          packages = [ pkgs.rust-analyzer ];
        };
      }
    );
}